plugins {
    id 'java'
}

apply from: 'libs.gradle'

def publishScript = file(rootProject.getProjectDir().getPath() + '/publish.gradle')
if (publishScript.exists()) {
    apply from: publishScript.path
}

project.group = projectGroup
project.version = projectVersion

repositories {
    mavenLocal()
    mavenCentral()
    maven { url 'https://hub.spigotmc.org/nexus/content/groups/public' }
    maven { url 'https://dmx-mc-project.gitlab.io/maven-repository/' }
}

def compileOnly2(library) {
    dependencies.compileOnly library.lib, {
        library.exclude.each { String excludeLibStr ->
            String[] excludeLib = excludeLibStr.split(':')
            exclude group: excludeLib[0], module: excludeLib[1]
        }
    }
}

def testImplementation2(library) {
    dependencies.testImplementation library.lib, {
        library.exclude.each { String excludeLibStr ->
            String[] excludeLib = excludeLibStr.split(':')
            exclude group: excludeLib[0], module: excludeLib[1]
        }
    }
}

dependencies {
    compileOnly libs.lombok
    annotationProcessor libs.lombok

    compileOnly2 libs.bukkit
    implementation libs.commons_text
    implementation libs.refobj

    testImplementation libs.test.junit5
    testImplementation libs.test.mock
    testImplementation2 libs.bukkit
    testImplementation libs.test.h2db
}

test {
    useJUnitPlatform()
}