build: переход на Gradle Kotlin DSL

build.gradle.kts

@@ -1,4 +1,4 @@
-wrapper {
+tasks.withType<Wrapper> {
     gradleVersion = "8.10"
     distributionType = Wrapper.DistributionType.BIN
 }

fluent-syntax/build.gradle

@@ -1,56 +0,0 @@
-plugins {
-    id("java")
-    id("maven-publish")
-}
-
-group = "ru.di9.fluent"
-version = "1.0-SNAPSHOT"
-
-java.toolchain {
-    languageVersion = JavaLanguageVersion.of(17)
-}
-
-repositories {
-    mavenLocal()
-    mavenCentral()
-}
-
-ext {
-    assertjVersion = "3.24.2"
-    gsonVersion = "2.9.1"
-    joorVersion = "0.9.15"
-    jsonAssertVersion = "1.5.1"
-    junitVersion = "5.9.2"
-    lombokVersion = "1.18.30"
-}
-
-dependencies {
-    annotationProcessor("org.projectlombok:lombok:$lombokVersion")
-    compileOnly("org.projectlombok:lombok:$lombokVersion")
-
-    testImplementation(platform("org.junit:junit-bom:$junitVersion"))
-    testImplementation("org.junit.jupiter:junit-jupiter")
-
-    testAnnotationProcessor("org.projectlombok:lombok:$lombokVersion")
-    testCompileOnly("org.projectlombok:lombok:$lombokVersion")
-    testImplementation("org.assertj:assertj-core:$assertjVersion")
-    testImplementation("com.google.code.gson:gson:$gsonVersion")
-    testImplementation("org.jooq:joor:$joorVersion")
-    testImplementation("org.skyscreamer:jsonassert:$jsonAssertVersion")
-}
-
-test {
-    useJUnitPlatform()
-}
-
-publishing {
-    publications {
-        mavenBinary(MavenPublication) {
-            groupId = project.group
-            artifactId = project.name
-            version = project.version
-
-            from components.java
-        }
-    }
-}

fluent-syntax/build.gradle.kts

@@ -0,0 +1,43 @@
+plugins {
+    java
+    id("maven-publish")
+}
+
+group = "ru.di9.fluent"
+version = "1.0-SNAPSHOT"
+
+java.toolchain {
+    languageVersion = JavaLanguageVersion.of(17)
+}
+
+repositories {
+    mavenLocal()
+    mavenCentral()
+}
+
+dependencies {
+    annotationProcessor(libs.lombok)
+    compileOnly(libs.lombok)
+
+    testImplementation(libs.junit)
+    testAnnotationProcessor(libs.lombok)
+    testCompileOnly(libs.lombok)
+    testImplementation(libs.assertj)
+    testImplementation(libs.gson)
+    testImplementation(libs.joor)
+    testImplementation(libs.jsonassert)
+}
+
+tasks.withType<Test> {
+    useJUnitPlatform()
+}
+
+publishing.publications {
+    create<MavenPublication>("mavenBinary") {
+        groupId = project.group.toString()
+        artifactId = project.name
+        version = project.version.toString()
+
+        from(components["java"])
+    }
+}

gradle/libs.versions.toml

@@ -0,0 +1,7 @@
+[libraries]
+lombok = { group = "org.projectlombok", name = "lombok", version = "1.18.30" }
+junit = { group = "org.junit.jupiter", name = "junit-jupiter", version = "5.9.2" }
+assertj = { group = "org.assertj", name = "assertj-core", version = "3.24.2" }
+gson = { group = "com.google.code.gson", name = "gson", version = "2.9.1" }
+joor = { group = "org.jooq", name = "joor", version = "0.9.15" }
+jsonassert = { group = "org.skyscreamer", name = "jsonassert", version = "1.5.1" }