//file:noinspection GroovyAssignabilityCheck
//file:noinspection GrUnresolvedAccess
plugins {
    id "groovy"
    id "java-gradle-plugin"
    id "maven-publish"
}

wrapper {
    gradleVersion = "8.7"
    distributionType = Wrapper.DistributionType.BIN
}

project.group = "ru.di9.gradle"
project.version = "1.1"

gradlePlugin.plugins {
    githooksPlugin {
        id = "ru.di9.gradle.githooks"
        displayName = "githooks plugin"
        description = "Simple githooks plugin"
        implementationClass = "ru.di9.gradle.githooks.GitHooksPlugin"
    }
}

publishing {
    publications {
        mavenBinary(MavenPublication) {
            groupId = project.group
            artifactId = project.name
            version = project.version

            from components.java
        }
    }

    repositories {
        maven {
            name = "Di9"
            url = uri("https://di9.ru/git/api/packages/Voomra/maven")
            def giteaToken = System.getenv("GITEA_TOKEN")

            credentials(HttpHeaderCredentials) {
                name = "Authorization"
                value = "token ${giteaToken}"
            }

            authentication {
                header(HttpHeaderAuthentication)
            }
        }
    }
}