//file:noinspection GroovyAssignabilityCheck
plugins {
    id 'java'
    id 'maven-publish'
}

wrapper {
    gradleVersion = '8.10'
    distributionType = Wrapper.DistributionType.BIN
}

compileJava {
    sourceCompatibility = targetCompatibility = JavaVersion.VERSION_17
    options.encoding = 'UTF-8'
}

group 'ru.di9'
version '1.9.3'

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    compileOnly('org.jetbrains:annotations:23.0.0')
    annotationProcessor('org.projectlombok:lombok:1.18.24')
    compileOnly('org.projectlombok:lombok:1.18.24')
}

publishing {
    publications {
        mavenBinary(MavenPublication) {
            groupId = project.group
            artifactId = project.name
            version = project.version

            from components.java
        }
    }

    repositories {
        maven {
            name = 'Di9'
            url = uri('https://di9.ru/git/api/packages/Voomra/maven')
            def giteaToken = System.getenv('GITEA_TOKEN')

            credentials(HttpHeaderCredentials) {
                name = 'Authorization'
                value = "token ${giteaToken}"
            }

            authentication {
                header(HttpHeaderAuthentication)
            }
        }
    }
}