plugins {
    id 'java'
    id 'maven-publish'
}

wrapper {
    gradleVersion = '8.10'
    distributionType = Wrapper.DistributionType.BIN
}

project.group = projectGroup
project.version = projectVersion

compileJava {
    sourceCompatibility = 1.8
    targetCompatibility = 1.8
    options.encoding = 'UTF-8'
}

repositories {
    mavenLocal()
    mavenCentral()
}

ext {
    lombok_version = '1.18.2'
}

dependencies {
    /* LOMBOK */
    annotationProcessor (group: 'org.projectlombok', name: 'lombok', version: lombok_version)
    compileOnly         (group: 'org.projectlombok', name: 'lombok', version: lombok_version)

    /* TESTING */
    testAnnotationProcessor (group: 'org.projectlombok', name: 'lombok', version: lombok_version)
    testCompileOnly         (group: 'org.projectlombok', name: 'lombok', version: lombok_version)
    testImplementation (group: 'junit', name: 'junit', version: '4.12')
}

publishing {
    publications {
        mavenBinary(MavenPublication) {
            groupId = project.group
            artifactId = project.name
            version = project.version

            from components.java
        }
    }

    repositories {
        maven {
            name = 'Di9'
            url = uri('https://di9.ru/git/api/packages/Voomra/maven')
            def giteaToken = System.getenv('GITEA_TOKEN')

            credentials(HttpHeaderCredentials) {
                name = 'Authorization'
                value = "token ${giteaToken}"
            }

            authentication {
                header(HttpHeaderAuthentication)
            }
        }
    }
}