//file:noinspection GroovyAssignabilityCheck
//file:noinspection GrUnresolvedAccess
plugins {
    id "java-library"
    id "maven-publish"
}

wrapper {
    gradleVersion = "8.6"
    distributionType = Wrapper.DistributionType.BIN
}

compileJava {
    sourceCompatibility = targetCompatibility = JavaVersion.VERSION_17
    options.encoding = "UTF-8"
}

group = "ru.di9"
version = "1.2.1"

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    api("it.unimi.dsi:fastutil:8.5.12")

    def junit5Version = "5.9.2"
    testImplementation("org.junit.jupiter:junit-jupiter-api:$junit5Version")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:$junit5Version")
}

test {
    useJUnitPlatform()
}

publishing {
    publications {
        mavenBinary(MavenPublication) {
            groupId = project.group
            artifactId = project.name
            version = project.version

            from components.java
        }
    }

    repositories {
        maven {
            name = "Di9"
            url = uri("https://di9.ru/git/api/packages/Voomra/maven")
            def giteaToken = System.getenv("GITEA_TOKEN")

            credentials(HttpHeaderCredentials) {
                name = "Authorization"
                value = "token ${giteaToken}"
            }

            authentication {
                header(HttpHeaderAuthentication)
            }
        }
    }
}